Okay, I think I figured out a way we can use the F/A-18 to gove us air support. We just need to figure out the F/A-18's name, instead of "A10LGB". Then we run this script, which I convinently found in the editor's depot (by Skumball):
;Airstrike (map click) v1.2
;by Skumball (simongoddard4@yahoo.co.uk)
;
;Thanks to Viriato for making the bombs fall correctly and LCD for incorporating the script into the radio
;
;Requires:
;OFP v1.85
;1 Pilot named "strikePilot"
;3 Markers ("spawn","safe","target" all set to 'empty')
;1 Trigger (Activation: Radio Alpha, Repeatedly. Text: Air Strike. On Activation: onMapSingleClick {[_pos] exec "airstrike.sqs"}; strikePilot sideChat "Give me a target")
;
;Have a look at the sample mission to see how it works
;Change the value of _num, *0.2 and ~0.2 for different results
onMapSingleClick {}
1 setRadioMsg "Null"
_pos = _this select 0
"target" setMarkerPos _pos
"target" setMarkerType "destroy"
strikePlane = "A10LGB" camCreate (getMarkerPos "spawn")
strikePlane setPos [(getPos strikePlane select 0),(getPos strikePlane select 1),(getPos strikePlane select 2)+800]
strikePlane setDir 180
strikePilot assignAsDriver strikePlane
strikePilot moveInDriver strikePlane
strikePilot doMove _pos
strikePilot sideChat "On the way"
@ unitReady strikePilot
strikePilot sideChat "Target aquired"
_num = 4
_i = 0
#loop
_bomb = "laserGuidedBomb" camCreate [(getPos strikePlane select 0)+((random 10)-5),(getPos strikePlane select 1)+((random 10)-5),(getPos strikePlane select 2)-3]
_bomb setDir (getDir strikePlane)
_bomb setVelocity [(velocity strikePlane select 0)*0.2,(velocity strikePlane select 1)*0.2,(velocity strikePlane select 2)*0.2]
_i = _i + 1
~0.2
? _i < _num : goto "loop"
strikePilot doMove (getMarkerPos "spawn")
strikePilot sideChat "Heading back"
"target" setMarkerType "empty"
@ unitReady strikePilot
deleteVehicle strikePlane
strikePilot setVelocity [0,0,0]
strikePilot setPos (getMarkerPos "safe")
strikePilot sideChat "Ready"
1 setRadioMsg "Air Strike"
exit
I think that would work for us. Only thing is we need to figure out a way that only allows the player to call that in again after a certain amount of time had passed.
EDIT: I think I solved that problem. Where it say's "1 setRadioMsg "Air Strike", put a ~50 (or however many seconds we would need), then it has to wait before the radio message is available again.