Home   Help Search Login Register  

Author Topic: Little scripting issues... [SOLVED]  (Read 2111 times)

0 Members and 1 Guest are viewing this topic.

Offline Krieg

  • Mission Maker
  • Members
  • *
  • Who dares wins.
Little scripting issues... [SOLVED]
« on: 02 Jan 2010, 12:11:41 »
I am having a bit of a scripting issue here.
I had created a script that puts a marker at certain unit and if that unit dies it puts it in position of another unit.
Of course, as most of my scripts it did not work :no:.

I really do not know what is the problem. I tried rebuilding the script and failed again.
Code: ("redwolfpos.sqs") [Select]
#loop
?(not alive b && not alive c && not alive d && not alive e) goto "Lastdown"
?(not alive b && alive c) : goto "1stdown"
?(not alive b && not alive c && alive d) : goto "2nddown"
?(not alive b && not alive c && not alive d && alive e) goto "3rddown"
"A" setMarkerPos getPos b
~0.5
goto "loop"

#redwolfdead
"A" setMarkerColor "ColorYellow"
~0.5
goto "redwolfdead"

#2nd
?(not alive b && not alive c && not alive d && not alive e) : goto "Lastdown"
?(not alive c && not alive b && alive d) : goto "2nddown"
?(not alive b && not alive c && not alive d && alive e) goto "3rddown"
"A" setMarkerPos getPos c
~0.5
goto "2nd"

#3rd
?(alive b; alive c; alive d; alive e) : goto "Lastdown"
?(not alive b && not alive c && not alive d && alive e) : goto "3rddown"
"A" setMarkerPos getPos d
~0.5
goto "3rd"

#4th
?(not alive b && not alive c && not alive d && not alive e) : goto "Lastdown"
"A" setMarkerPos getPos e
~0.5
goto "4th"

#1stdown
~1
c sideChat "Dammit! Red Wolf 1 down! I repeat, Red Wolf 1 is down! Red Wolf 2 taking command!"
goto "2nd"

#2nddown
~1
d sideChat "Damn! Red Wolf 2 is down! Red Wolf 3 taking command!"
~2
d sideChat "Red Wolf to Red Grinder! We are getting pounded out here! We need support ASAP!"
goto "3rd"

#3rddown
~1
e sideChat "Red Wolf 3 is down! Red Grinder, we are DYING out here! We need support NOW!"
~2
e sideChat "Red Wolf 4 taking command. I say again, Red Wolf 4 taking command.
goto "4th"

#Lastdown
~1
player sideChat "Red Wolf! Come in Red Wolf! Red Wolf do you read me? Red Wolf please respond!"
~2
player groupChat "Dammit! Red Wolf is down!"
goto "redwolfdead"

Thanks for the help,
Krieg
« Last Edit: 02 Feb 2010, 16:02:02 by Krieg »
If you see a light at the end of the tunnel, then it's probably an enemy tank.

Offline savedbygrace

  • Intel Depot
  • Administrator
  • *****
  • Be swift to hear...slow to speak...slow to wrath.
Re: Little scripting issues...
« Reply #1 on: 02 Jan 2010, 18:18:14 »
It's sort of disorganized and confusing really..Your first mistake was the more than a few missing colons":"
You're also setting marker positions for units that are already dead

Try naming the group by placing this in the leaders init field
RedWolf = group this
Then you have only to check for the health of the leader.

Code: [Select]
_count = 0


#LeaderCheck
?!(alive leader RedWolf) : goto "LeaderDown"
"A" setMarkerPos getPos leader RedWolf
~0.5
goto "LeaderCheck"

#LeaderDown
_count = _count + 1
? _count <= 1 : goto "2nd"
? _count <= 2 : goto "3rd"
? _count <= 3 : goto "4th"
? _count <= 4 : goto "Last"


#2nd
;Pause to allow next unit to assume leader role
~2
leader RedWolf sideChat "Damn! Red Wolf 2 is down! Red Wolf 3 taking command!"
goto "LeaderCheck"

#3rd
;Pause to allow next unit to assume leader role
~2
leader RedWolf sideChat "Damn! Red Wolf 2 is down! Red Wolf 3 taking command!"
~2
leader RedWolf sideChat "Red Wolf to Red Grinder! We are getting pounded out here! We need support ASAP!"
goto "LeaderCheck"

#4th
;Pause to allow next unit to assume leader role
~2
leader RedWolf sideChat "Red Wolf 3 is down! Red Grinder, we are DYING out here! We need support NOW!"
~2
leader RedWolf sideChat "Red Wolf 4 taking command. I say again, Red Wolf 4 taking command."
goto "LeaderCheck"

#Last
player sideChat "Red Wolf! Come in Red Wolf! Red Wolf do you read me? Red Wolf please respond!"
~2
player groupChat "Dammit! Red Wolf is down!"
"A" setMarkerColor "ColorYellow"

Exit

It's not tested but it should work well enough to notify the player of RedWolf's status. You may have to tweak the delay in the sidechats depending on how long it takes the AI to recogize that their leader is dead.

« Last Edit: 03 Feb 2010, 09:34:03 by savedbygrace »

Offline Krieg

  • Mission Maker
  • Members
  • *
  • Who dares wins.
Re: Little scripting issues...
« Reply #2 on: 02 Jan 2010, 18:25:15 »
Thanks for response, savedbygrace, testing it right now!  :good:

Edit: Unfortunately it did not work.
See attached missionete to see if it is me who is doing something wrong.
« Last Edit: 02 Jan 2010, 18:27:04 by Krieg »
If you see a light at the end of the tunnel, then it's probably an enemy tank.

Walter_E_Kurtz

  • Guest
Re: Little scripting issues...
« Reply #3 on: 02 Jan 2010, 18:43:40 »
There were only a couple of errors in what you had originally, Krieg
Quote
?(alive b; alive c; alive d; alive e) : goto "Lastdown"   <---   incorrect use of semi colons

e sideChat "Red Wolf 4 taking command. I say again, Red Wolf 4 taking command.   <---   Needs speech mark to end the quotation
Then I removed the repeated 'not alive ...' checks, made sure units are alive to say things and removed the readwolfdead loop.

Code: (redwolfpos.sqs) [Select]
#loop
?(!alive b && !alive c && !alive d && !alive e) goto "Lastdown"
?(!alive b && alive c) : goto "1stdown"
?(!alive b && !alive c && alive d) : goto "2nddown"
?(!alive b && !alive c && !alive d && alive e) goto "3rddown"
"A" setMarkerPos getPos b
~0.5
goto "loop"

#2nd
?(!alive c && !alive d && !alive e) : goto "Lastdown"
?(!alive c && alive d) : goto "2nddown"
?(!alive c && !alive d && alive e) goto "3rddown"
"A" setMarkerPos getPos c
~0.5
goto "2nd"

#3rd
?(!alive d && !alive e) : goto "Lastdown"
?(!alive d && alive e) : goto "3rddown"
"A" setMarkerPos getPos d
~0.5
goto "3rd"

#4th
?(!alive e) : goto "Lastdown"
"A" setMarkerPos getPos e
~0.5
goto "4th"

#1stdown
~1
? alive c: c sideChat "Dammit! Red Wolf 1 down! I repeat, Red Wolf 1 is down! Red Wolf 2 taking command!"
goto "2nd"

#2nddown
~1
? alive d: d sideChat "Damn! Red Wolf 2 is down! Red Wolf 3 taking command!"
~2
? alive d: d sideChat "Red Wolf to Red Grinder! We are getting pounded out here! We need support ASAP!"
goto "3rd"

#3rddown
~1
? alive e: e sideChat "Red Wolf 3 is down! Red Grinder, we are DYING out here! We need support NOW!"
~2
? alive e: e sideChat "Red Wolf 4 taking command. I say again, Red Wolf 4 taking command."
goto "4th"

#Lastdown
~1
player sideChat "Red Wolf! Come in Red Wolf! Red Wolf do you read me? Red Wolf please respond!"
~2
player groupChat "Dammit! Red Wolf is down!"

"A" setMarkerColor "ColorYellow"
exit

Offline Krieg

  • Mission Maker
  • Members
  • *
  • Who dares wins.
Re: Little scripting issues...
« Reply #4 on: 02 Jan 2010, 19:06:47 »
Thanks for the response Walter_E_Kurtz!

There is some improvement (marker moves to Red Wolf's original) leader, but marker does not either move from red wolf leader nor does it turn Yellow when all red wolf units are dead. But at least it got into original leader's position, and no sideChat was received.
If you see a light at the end of the tunnel, then it's probably an enemy tank.

Walter_E_Kurtz

  • Guest
Re: Little scripting issues...
« Reply #5 on: 02 Jan 2010, 20:04:01 »
Missing colons !

The following ought to be correct, finally:
Code: (redwolfpos.sqs) [Select]
#loop
?(!alive b && !alive c && !alive d && !alive e) : goto "Lastdown"
?(!alive b && alive c) : goto "1stdown"
?(!alive b && !alive c && alive d) : goto "2nddown"
?(!alive b && !alive c && !alive d && alive e) : goto "3rddown"
"A" setMarkerPos getPos b
~0.5
goto "loop"

#2nd
?(!alive c && !alive d && !alive e) : goto "Lastdown"
?(!alive c && alive d) : goto "2nddown"
?(!alive c && !alive d && alive e) : goto "3rddown"
"A" setMarkerPos getPos c
~0.5
goto "2nd"

#3rd
?(!alive d && !alive e) : goto "Lastdown"
?(!alive d && alive e) : goto "3rddown"
"A" setMarkerPos getPos d
~0.5
goto "3rd"

#4th
?(!alive e) : goto "Lastdown"
"A" setMarkerPos getPos e
~0.5
goto "4th"

#1stdown
~1
? alive c : c sideChat "Dammit! Red Wolf 1 down! I repeat, Red Wolf 1 is down! Red Wolf 2 taking command!"
goto "2nd"

#2nddown
~1
? alive d : d sideChat "Damn! Red Wolf 2 is down! Red Wolf 3 taking command!"
~2
? alive d : d sideChat "Red Wolf to Red Grinder! We are getting pounded out here! We need support ASAP!"
goto "3rd"

#3rddown
~1
? alive e : e sideChat "Red Wolf 3 is down! Red Grinder, we are DYING out here! We need support NOW!"
~2
? alive e : e sideChat "Red Wolf 4 taking command. I say again, Red Wolf 4 taking command."
goto "4th"

#Lastdown
~1
player sideChat "Red Wolf! Come in Red Wolf! Red Wolf do you read me? Red Wolf please respond!"
~2
player groupChat "Dammit! Red Wolf is down!"

"A" setMarkerColor "ColorYellow"
exit

Offline Krieg

  • Mission Maker
  • Members
  • *
  • Who dares wins.
Re: Little scripting issues...
« Reply #6 on: 02 Jan 2010, 21:01:53 »
This one works perfectly!
Now just to make case for each possible outcome (i.e. 3 getting shot and leader still being alive, since the script for now just activates if you kill everyone in order).

Thanks for the help everyone my problem is solved,
Krieg

Edit: And I managed to get it un-solved. Apparently, when I put additional cases (i.e. when Red Wolf 1 is still alive, and Red Wolf 3 goes KIA), I managed to get infnitive loop of messages saying "Red Wolf 3 is down! I repeat Red Wolf 3 is down!", so I could build additional loops that would not have condition
Code: [Select]
?(alive b && !alive c) in them, but I thought this would make the script unnecessary complicated. Who needs more loops when there are global variables, right? Right...
So I change the script which now looks like this:
Code: [Select]
_redwolf12 = 0
_redwolf13 = 0
_redwolf14 = 0

#loop
?(!alive b && !alive c && !alive d && !alive e) : goto "Lastdown"
?(!alive b && alive c) : goto "1stdown"
?(!alive b && !alive c && alive d) : goto "2nddown"
?(!alive b && !alive c && !alive d && alive e) : goto "3rddown"
?(alive b && !alive c && _redwolf12 = 0) : goto "Leader1st"
?(alive b && !alive d && _redwolf13 = 0) : goto "Leader2nd"
?(alive b && !alive e && _redwolf14 = 0) : goto "Leader3rd"
"A" setMarkerPos getPos b
~0.5
goto "loop"

#2nd
?(!alive c && !alive d && !alive e) : goto "Lastdown"
?(!alive c && alive d) : goto "2nddown"
?(!alive c && !alive d && alive e) : goto "3rddown"
?(alive c && !alive d && _redwolf13 = 0) : goto "2ndLead1st"
?(alive c && !alive e && _redwolf14 = 0) : goto "2ndLead2nd"
"A" setMarkerPos getPos c
~0.5
goto "2nd"

#3rd
?(!alive d && !alive e) : goto "Lastdown"
?(!alive d && alive e) : goto "3rddown"
?(alive d && !alive e && _redwolf14 = 0) : goto "3rdLead1st"
"A" setMarkerPos getPos d
~0.5
goto "3rd"

#4th
?(!alive e) : goto "Lastdown"
"A" setMarkerPos getPos e
~0.5
goto "4th"

#1stdown
~1
? alive c : c sideChat "Dammit! Red Wolf 1 down! I repeat, Red Wolf 1 is down! Red Wolf 2 taking command!"
goto "2nd"

#2nddown
~1
? alive d : d sideChat "Damn! Red Wolf 2 is down! Red Wolf 3 taking command!"
~2
? alive d : d sideChat "Red Wolf to Red Grinder! We are getting pounded out here! We need support ASAP!"
goto "3rd"

#3rddown
~1
? alive e : e sideChat "Red Wolf 3 is down! Red Grinder, we are DYING out here! We need support NOW!"
~2
? alive e : e sideChat "Red Wolf 4 taking command. I say again, Red Wolf 4 taking command."
goto "4th"

#Leader1st
~0.2
? alive b : b sideChat "Goddammit! Red Wolf 2 is down!"
_redwolf12 = _redwolf12 + 1
goto "loop"

#Leader2nd
~0.2
? alive b : b sideChat "Red Wolf 3 is down! I repeat, Red Wolf 3 is down!"
_redwolf13 = _redwolf13 + 1
goto "loop"

#Leader3rd
~0.2
? alive b : b sideChat "F***! Red Wolf 4 is down! We might need some help out here, Red Grinder!"
_redwolf14 = _redwolf14 + 1
goto "loop"

#2ndLead1st
~0.2
? alive c : c sideChat "Damn! Red Wolf 3 is down!"
_redwolf13 = _redwolf13 + 1
goto "2nd"

#2ndLead2nd
~0.2
? alive c : c sideChat "Red Wolf 4 is KIA! I repeat, Red Wolf 4 is KIA!"
_redwolf14 = _redwolf14 + 1
goto "2nd"

#3rdLead1st
~0.2
? alive d : d sideChat "Red Wolf 4 is down! We need support ASAP!"
_redwolf14 = _redwolf14 + 1
goto "3rd"

#Lastdown
~1
player sideChat "Red Wolf! Come in Red Wolf! Red Wolf do you read me? Red Wolf please respond!"
~2
player groupChat "Dammit! Red Wolf is down!"

"A" setMarkerColor "ColorYellow"
exit

But whenever I try to run the script, following happens:
I get an error saying
Code: [Select]
Error! ?(alive d && !alive e && _redwolf14 |#| = 0) Unknown operator!
I am not sure if adding additional ('s to script will do any good.
In example:
Code: [Select]
?(alive d && !alive e && (_redwolf14 = 0))
« Last Edit: 03 Jan 2010, 09:52:18 by Krieg »
If you see a light at the end of the tunnel, then it's probably an enemy tank.

Offline RKurtzDmitriyev

  • Former Staff
  • ****
Re: Little scripting issues...
« Reply #7 on: 03 Jan 2010, 14:04:10 »
I am not sure if adding additional ('s to script will do any good.
In example:
Code: [Select]
?(alive d && !alive e && (_redwolf14 = 0))

I would try that first. "Unknown operator!" sounds like a syntax error. I suggest making a smaller script for testing, and fiddling around with that same line of code until it works.

EDIT: Is _redwolf14 supposed to be a number or a boolean value? If it's a number, = has to be changed to == . If it's boolean, I'm not sure if OFP recognizes 0 as a synonym for "false." Try writing

Code: [Select]
!_redwolf14
or

Code: [Select]
_redwolf14 = false
instead.

Just 2 cents, hope it helps.  :P
« Last Edit: 03 Jan 2010, 14:17:10 by RKurtzDmitriyev »
The OFP Editing Center wishes to remind you that the faithful COMREF will never threaten to stab you and, in fact, cannot speak.
However, in the event that it does speak, you are encouraged to heed its advice. ;)

Offline Krieg

  • Mission Maker
  • Members
  • *
  • Who dares wins.
Re: Little scripting issues...
« Reply #8 on: 03 Jan 2010, 14:29:45 »
This seems to be answer to my question! It is meant to be number, so it would prevent sideChat from looping and to prevent other units from reporting that certain units are down when they are already reported to player.

Lots of that, RKurtzDimitriyev!  :good:

Edit: Works perfectly! This script is ready to be implemented into current pre-alpha version of The Red Grinder II.
« Last Edit: 03 Jan 2010, 14:40:18 by Krieg »
If you see a light at the end of the tunnel, then it's probably an enemy tank.

Offline Krieg

  • Mission Maker
  • Members
  • *
  • Who dares wins.
Re: Little scripting issues...
« Reply #9 on: 01 Feb 2010, 19:25:07 »
Another reincarnation.

Apparently, script I used did not function completely.
It seems that OFP engine does not care about crew as long as tank itself is okay, this means that even after all of Red Wolf's crew was dead, Red Wolf itself was still listed as alive.
I tired modifying the script so it detects status of the crew.
Code: [Select]
_redwolf12 = 0
_redwolf13 = 0
_redwolf14 = 0

#loop
?(!alive f1 && !alive f2 && !alive f3 && !alive g1 && !alive g2 && ! alive g3 && !alive h1 && !alive h2 && !alive h3 && !alive i1 && !alive i2 && !alive i3) : goto "Lastdown"
?(!alive f1 && !alive f2 && !alive f3 && alive g1 || alive g2 || alive g3) : goto "1stdown"
?(!alive f1 && !alive f2 && !alive f3 && !alive g1 && !alive g2 && !alive g3 && alive h1 || alive h2 || alive h3) : goto "2nddown"
?(!alive f1 && !alive f2 && !alive f3 && !alive g1 && !alive g2 && !alive g3 && !alive h1 && !alive h2 && !alive h3 && alive i1 || alive i2 || alive i3) : goto "3rddown"
?((alive f1 || alive f2 || alive f3) && !alive g1 && !alive g2 && !alive g3 && _redwolf12 == 0) : goto "Leader1st"
?((alive f1 || alive f2 || alive f3) && !alive h1 && !alive h2 && !alive h3 && _redwolf13 == 0) : goto "Leader2nd"
?((alive f1 || alive f2 || alive f3) && !alive i1 && !alive i2 && !alive i3 && _redwolf14 == 0) : goto "Leader3rd"
"A" setMarkerPos getPos b
~0.5
goto "loop"

#2nd
?(!alive g1 && !alive g2 && !alive g3 && !alive h1 && !alive h2 && !alive h3 && !alive i1 && !alive i2 && !alive i3) : goto "Lastdown"
?(!alive g1 && !alive g2 && !alive g3 && alive h1 || alive h2 || alive h3) : goto "2nddown"
?(!alive g1 && !alive g2 && !alive g3 && !alive h1 && !alive h2 && !alive h3 && alive i1 || alive i2 || alive i3) : goto "3rddown"
?((alive g1 || alive g2 || alive g3) && !alive h1 && !alive h2 && !alive h3 && _redwolf13 == 0) : goto "2ndLead1st"
?((alive g1 || alive g2 || alive g3) && !alive i1 && !alive i2 && !alive i3 && _redwolf14 == 0) : goto "2ndLead2nd"
"A" setMarkerPos getPos c
~0.5
goto "2nd"

#3rd
?(!alive h1 && !alive h2 && !alive h3 && !alive i1 && !alive i2 && !alive i3) : goto "Lastdown"
?(!alive h1 && !alive h2 && !alive h3 && alive i1 || alive i2 || alive i3) : goto "3rddown"
?((alive h1 || alive h2 || alive h3) && !alive i1 && !alive i2 && !alive i3 && _redwolf14 == 0) : goto "3rdLead1st"
"A" setMarkerPos getPos d
~0.5
goto "3rd"

#4th
?(!alive i1 && !alive i2 && !alive i3) : goto "Lastdown"
"A" setMarkerPos getPos e
~0.5
goto "4th"

#1stdown
~1
? alive c : c sideChat "Dammit! Red Wolf 1 down! I repeat, Red Wolf 1 is down! Red Wolf 2 taking command!"
goto "2nd"

#2nddown
~1
? alive d : d sideChat "Damn! Red Wolf 2 is down! Red Wolf 3 taking command!"
~2
? alive d : d sideChat "Red Wolf to Red Grinder! We are getting pounded out here! We need support ASAP!"
goto "3rd"

#3rddown
~1
? alive e : e sideChat "Red Wolf 3 is down! Red Grinder, we are DYING out here! We need support NOW!"
~2
? alive e : e sideChat "Red Wolf 4 taking command. I say again, Red Wolf 4 taking command."
goto "4th"

#Leader1st
~0.2
? alive b : b sideChat "Goddammit! Red Wolf 2 is down!"
_redwolf12 = _redwolf12 + 1
goto "loop"

#Leader2nd
~0.2
? alive b : b sideChat "Red Wolf 3 is down! I repeat, Red Wolf 3 is down!"
_redwolf13 = _redwolf13 + 1
goto "loop"

#Leader3rd
~0.2
? alive b : b sideChat "F***! Red Wolf 4 is down! We might need some help out here, Red Grinder!"
_redwolf14 = _redwolf14 + 1
goto "loop"

#2ndLead1st
~0.2
? alive c : c sideChat "Damn! Red Wolf 3 is down!"
_redwolf13 = _redwolf13 + 1
goto "2nd"

#2ndLead2nd
~0.2
? alive c : c sideChat "Red Wolf 4 is KIA! I repeat, Red Wolf 4 is KIA!"
_redwolf14 = _redwolf14 + 1
goto "2nd"

#3rdLead1st
~0.2
? alive d : d sideChat "Red Wolf 4 is down! We need support ASAP!"
_redwolf14 = _redwolf14 + 1
goto "3rd"

#Lastdown
~1
player sideChat "Red Wolf! Come in Red Wolf! Red Wolf do you read me? Red Wolf please respond!"
~2
player groupChat "Dammit! Red Wolf is down!"

"A" setMarkerColor "ColorYellow"
exit

Unfortunately it activates all radio messages (and presumably rest of the script) until "Red Wolf 4 taking command!" part.

I suspect that this is result of misusing "||".

Thanks,
Krieg
If you see a light at the end of the tunnel, then it's probably an enemy tank.

Offline RKurtzDmitriyev

  • Former Staff
  • ****
Re: Little scripting issues...
« Reply #10 on: 02 Feb 2010, 15:02:59 »
That's quite a monster of a script you've got there, Krieg. :blink:

I'm taking a look at it now. But off the top of my head, about || : if you have two conditions, condition1 and condition2, then

Code: [Select]
condition1 || condition2
will be true if

(1) condition1 is true, condition2 is false
(2) condition1 is false, condition2 is true
(3) condition1 is true, condition2 is true

It will be false if and only if:

(4) condition1 is false, condition2 is false

If you understand that, and you remembered to place parentheses properly, then I'm not sure how you could have misused || .

EDIT: I think it's a parentheses problem. Take this line, for example:

Code: [Select]
?(!alive f1 && !alive f2 && !alive f3 && alive g1 || alive g2 || alive g3) : goto "1stdown"
The engine is probably interpreting that to mean:

Code: [Select]
?((!alive f1 && !alive f2 && !alive f3 && alive g1) || (alive g2) || (alive g3)) : goto "1stdown"
And that makes it go to 1stdown if g2 is alive. Presumably he's alive at the start of the mission, so it goes to 1stdown immediately. You probably want

Code: [Select]
?((!alive f1 && !alive f2 && !alive f3) && (alive g1 || alive g2 || alive g3)) : goto "1stdown"
And et cetera for similar lines throughout the whole script. Now it should go to 1stdown if f1, f2, and f3 are all dead, and any of the g's are alive.
« Last Edit: 02 Feb 2010, 15:17:53 by RKurtzDmitriyev »
The OFP Editing Center wishes to remind you that the faithful COMREF will never threaten to stab you and, in fact, cannot speak.
However, in the event that it does speak, you are encouraged to heed its advice. ;)

Offline Krieg

  • Mission Maker
  • Members
  • *
  • Who dares wins.
Re: Little scripting issues...
« Reply #11 on: 02 Feb 2010, 15:25:18 »
My largest script yet. And when I think that it started with
Code: [Select]
#loop
"A" setMarkerPos getPos b
~0.5
goto "loop"

But there is a script that deserves it's respectable place as OFP's Largest Script. I found it in Sui's The Black Gap mission... operation.sqs. 148kb large. And my 'monster' script is only 4kb.

On Topic:

Hmm... It seems that then I did not misuse ||. Although, I still had more than two conditions. Three. One for each crewman. But I do not think that that is causing my problem.

Edit: That could be it. I'll test it right away!
Thanks for response!

Edit 2: Thanks again! It works perfectly!
« Last Edit: 02 Feb 2010, 16:01:49 by Krieg »
If you see a light at the end of the tunnel, then it's probably an enemy tank.